İDD risk ağırlığı formülü Excel'de

Kurumsal ve perakende İDD risk ağırlığını mevcut BDDK düzenlemesine ve taslağa göre hesaplayan, çalışma sayfasına yapıştırılacak formüller ve sonucu doğrulamak için değerler.

İDD risk ağırlığı formülü yalnız iki istatistik işlevi gerektirir: standart normal dağılım NORM.S.DAĞ ve tersi NORM.S.TERS. TO %1, THK %40 ve 2,5 yıl vade ile aşağıdaki formüller kurumsal alacak için taslağa göre %82,06, 1,06 ölçek faktörünü uygulayan mevcut İDD Tebliği'ne göre %86,98 risk ağırlığı verir; hesaplayıcının sonucuyla aynıdır.

Formüller Türkçe Excel yazımıyla verilmiştir: işlev adları Türkçe, bağımsız değişken ayırıcısı noktalı virgül, ondalık ayırıcı virgüldür. İngilizce Excel için İngilizce sayfadaki yazımı kullanın.

Girdiler

TO ve THK ondalık sayı olarak girilir: %1, 0,01 demektir. Taslakta içsel THK tahmininin tabanını girmeden önce uygulayın; örneğin teminatsız kurumsal alacakta %25.

HücreGirdiÖrnek
B1TO0,01
B2THK0,40
B3Vade (V), yıl, 1 ile 5 arası2,5
B4Ölçek faktörü: taslakta 1, mevcut düzenlemede 1,061
B5TO tabanı: taslakta 0,0005 (nitelikli rotatif perakendede 0,001), mevcut düzenlemede 0,00030,0005
B6Temerrüt anındaki risk tutarı (TT)10000000

Kurumsal alacaklar

B7, tabandan sonra TO:

=MAK(B1;B5)

B8, korelasyon R:

=0,12*(1-ÜS(-50*B7))/(1-ÜS(-50))+0,24*(1-(1-ÜS(-50*B7))/(1-ÜS(-50)))

B9, vade düzeltmesi b:

=(0,11852-0,05478*LN(B7))^2

B10, sermaye yükümlülüğü K:

=(B2*NORM.S.DAĞ((NORM.S.TERS(B7)+KAREKÖK(B8)*NORM.S.TERS(0,999))/KAREKÖK(1-B8);DOĞRU)-B7*B2)*(1+(B3-2,5)*B9)/(1-1,5*B9)

B11, risk ağırlığı; hücreyi yüzde olarak biçimlendirin:

=B10*12,5*B4

B12, risk ağırlıklı tutar, ve B13, %8 sermaye yükümlülüğü:

=B11*B6
=B12*0,08

Örnek girdilerle kontrol değerleri: R = 0,192784, b = 0,137486, K = 0,065648, risk ağırlığı %82,06, RAT 8.205.938 ve sermaye 656.475. Hesaplayıcı normal dağılım için sayısal bir yaklaşım kullandığından RAT 8.205.940 gösterir; fark %0,00003'ün altındadır. B4 = 1,06 ve B5 = 0,0003 ile risk ağırlığı %86,98'dir.

Kurumsal KOBİ alacağında konsolide yıllık ciroyu milyon TL olarak B14'e, uygulanacak Kurul sınırı C'yi milyon TL olarak B15'e girin ve B8'deki R yerine şunu kullanın; mevcut düzenlemede C = 1000:

=0,12*(1-ÜS(-50*B7))/(1-ÜS(-50))+0,24*(1-(1-ÜS(-50*B7))/(1-ÜS(-50)))-0,04*(1-(MİN(MAK(B14;B15/10);B15)-B15/10)/(B15-B15/10))

Perakende alacaklar

Perakende formüllerinde vade düzeltmesi yoktur. B1–B7 ve B11–B13 aynı kalır; B8 ve B10 değişir. Taslakta THK tabanları ikamet amaçlı ipotekte %5, nitelikli rotatif perakendede %50 ve teminatsız diğer perakendede %30'dur.

B8, korelasyon R: ikamet amaçlı gayrimenkul ipotekli alacakta 0,15, nitelikli rotatif perakendede 0,04, diğer perakende alacaklarda:

=0,03*(1-ÜS(-35*B7))/(1-ÜS(-35))+0,16*(1-(1-ÜS(-35*B7))/(1-ÜS(-35)))

B10, sermaye yükümlülüğü K:

=B2*NORM.S.DAĞ((NORM.S.TERS(B7)+KAREKÖK(B8)*NORM.S.TERS(0,999))/KAREKÖK(1-B8);DOĞRU)-B7*B2

Kontrol değerleri: TO %1, THK %20 ve R = 0,15 olan konut ipotekli alacağın taslağa göre risk ağırlığı %25,07'dir. TO %5 ve THK %60 olan diğer perakende alacağın mevcut düzenlemeye göre risk ağırlığı %93,87'dir.

Çalışma kitabını indirin

İDD risk ağırlığı çalışma kitabı (.xlsx), bu formülleri mevcut BDDK düzenlemesi ve BDDK taslağı sayfalarında 50 alacak için içerir. A sütununda alacak sınıfını seçin; TO, THK, vade, kurumsal KOBİ için yıllık ciro ve TT girin. Sayfa, parametre tablosundaki TO tabanını ve teminatsız THK tabanını uygular; korelasyon, K, risk ağırlığı, RAT ve sermayeyi verir. Taslak sayfasında kurumsal KOBİ için Kurul sınırı C'yi Q3 hücresine girin. Çalışma kitabı ücretsizdir, korumasızdır ve makro içermez. Örnek satırlar yukarıdaki kontrol değerlerini verir. Excel, işlev adlarını kendi dilinde gösterir.

Diğer tablo programları

  • İngilizce Excel, Google E-Tablolar ve LibreOffice Calc İngilizce işlev adlarını kullanır: MAX, MIN, EXP, SQRT, NORM.S.DIST, NORM.S.INV, TRUE. Ayırıcılar programın dil ayarına bağlıdır.

İlgili sayfalar

Resmî kaynaklar ve kapsam

BDDK İDD Tebliği: risk ağırlığı formülleri ve TO tabanı; BDDK İDD Tebliği taslağı: TO ve THK tabanları, ölçek faktörünün kaldırılması; Basel Framework CRE31. Formüller tek, temerrüde düşmemiş alacağı kapsar; kredi riski azaltımı, finansal kuruluşlar için 1,25 çarpanı ve çıktı tabanı dahil değildir. Son gözden geçirme tarihi düzenlemelerin yürürlük tarihi değildir.

Son gözden geçirme: